Aminet 8/Aminet 8 (1995)(GTI - Schatztruhe)[!][Oct 1995].iso/Aminet/util/time/taxSched12.lha/taxScheduler/Install taxScheduler

Text File | 1995-08-19 | 8KB | 315 lines

; Installer installation script for taxScheduler
;$VER: Install 1.0 (19 July 1995)

(set @default-dest "")

(set program "taxScheduler")
(set progver "1.2")
(set helpdir "help:")
(set catalogdir "locale:catalogs/")

;================================================================================
; English strings

(set catalog-language 1)
(set guide-language 0)

(set #bad-kick
   (cat "You must have Kickstart 2.04 or higher installed to use taxScheduler!")
)

(set #install
   (cat "\nWelcome to " program " installation utility.\n\n"
        "This script installs " program " v" progver "\n"
        "on your Amiga.\n\n\n"
        program " © Copyright 1995 Oliver Kasper\n"
        "All rights reserved\n\n"
        "(MUI © Stephan Stuntz)")
)


(set #where-program
   (cat "Where do you want to install " program "?")
)

(set #copying
   (cat "Copying ")
)

(set #where-regprog
   (cat "Where do you want to install taxSchedulerReg?")
)

(set #which-catalogs
   (cat "Which catalogs should be installed?")
)
(set #which-catalogs-help
   (cat program " supports different languages. "
        "A catalog file must be copied to your harddisk "
        "for each language supported.\n\n"
        "To reduce the amount of space consumed by the catalog "
        "files, you can select to have only the files of specific "
        "languages copied.\n\n"
        "Simply check the boxes of the languages you wich to have "
        "available on your system.\n\n")
)
(set #where-catalog
   (cat "Where do you want to install the catalogfile?")
)

(set #which-docs
   (cat "Which docs should be installed?")
)
(set #which-docs-help
   (cat program " supports online help in different languages. "
        "A amigaguide file must be copied to your harddisk "
        "for each language supported.\n\n"
        "To reduce the amount of space consumed by the guide "
        "files, you can select to have only the files of specific "
        "languages copied.\n\n"
        "Simply check the boxes of the languages you wich to have "
        "available on your system.\n\n")
)
(set #where-doc
   (cat "Where do you want to install the documentation?")
)

;================================================================================
; German strings

(if (= @language "deutsch")
   (
      (set catalog-language 0)
      (set guide-language 1)

      (set #bad-kick
         (cat "Um " program " zu benutzen, benötigen sie mindestens Kickstart 2.04!")
      )

      (set #install
         (cat "\nHerzlich Willkommen zum " program"-Installationsprogramm.\n\n"
              "Dieses Skript installiert "
              program " v" progver "\n"
              "auf ihrem Amiga.\n\n\n"
              program " Copyright © 1995 Oliver Kasper\n"
              "Alle Rechte vorbehalten\n\n"
              "(MUI © Stephan Stuntz)")
      )


      (set #where-program
         (cat "Wo möchten Sie " program " installieren?")
      )

      (set #copying
         (cat "Kopieren von ")
      )

      (set #where-regprog
         (cat "Wo möchten Sie taxSchedulerReg installieren?")
      )

      (set #which-catalogs
         (cat "Welche Sprachen sollen installiert werden?")
      )
      (set #which-catalogs-help
         (cat program " unterstützt verschiedene Sprachen. "
              "Für jede Sprache muß eine Catalog-Datei auf ihre "
              "Festplatte kopiert werden.\n\n"
              "Um Platz zu sparen, brauchen sie nur die gewünschten "
              "Sprachen auszuwählen.\n\n "
              "Selektieren sie einfach die Sprachen, die sie auf "
              "ihrem System benutzen wollen.\n\n")
      )
      (set #where-catalog
         (cat "Wo soll die Catalogdatei installiert werden?")
      )

      (set #which-docs
         (cat "Welche Anleitungen sollen installiert werden?")
      )
      (set #which-docs-help
         (cat program " unterstützt Onlinehilfe in verschiedenen Sprachen. "
              "Für jede Sprache muß eine Amigaguide-Datei auf ihre "
              "Festplatte kopiert werden.\n\n"
              "Um Platz zu sparen, brauchen sie nur die gewünschten "
              "Sprachen auszuwählen.\n\n "
              "Selektieren sie einfach die Sprachen, die sie auf "
              "ihrem System benutzen wollen.\n\n")
      )
      (set #where-doc
         (cat "Wo soll die Anleitung installiert werden?")
      )
   )
)

;================================================================================
; make sure we are running under a 2.04 ROM

(if (< (/ (getversion) 65536) 37)
   (
      (abort #bad-kick)
   )
)

;================================================================================
;

(complete 0)

(message
   (#install)
)

(welcome)

(set destination
   (askdir
      (prompt #where-program)
      (help @askdir-help)
      (default "SYS:WBStartup")
   )
)

(copylib
   (prompt "\n" #copying program)
   (help @copylib-help)
   (source program)
   (dest destination)
   (confirm)
)

(complete 12)

(if (NOT (exists (tackon destination (cat program ".info"))))
   (
      (copyfiles
         (source (cat program ".info"))
         (dest destination)
      )
   )
)

(complete 25)

(set destination
   (askdir
      (prompt #where-regprog)
      (help @askdir-help)
      (default "SYS:Tools")
   )
)

(copylib
   (prompt "\n" #copying "taxSchedulerReg")
   (help @copylib-help)
   (source "taxSchedulerReg")
   (dest destination)
   (confirm)
)

(complete 37)

(if (NOT (exists (tackon destination "taxSchedulerReg.info")))
   (
      (copyfiles
         (source "taxSchedulerReg.info")
         (dest destination)
      )
   )
)

(complete 50)

(
   (set lang
      (askoptions
         (prompt #which-catalogs)
         (help #which-catalogs-help @askoptions-help)
         (choices "English")
         (default catalog-language)
      )
   )
   (set n 0)
   (while
      (set language
         (select n
            "english"
            ""
         )
      )
      (
         (if (IN lang n)
            (
               (set destination
                  (askdir
                     (prompt #where-doc)
                     (help @askdir-help)
                     (default (tackon catalogdir language))
                     )
               )

               (copyfiles
                  (source (tackon (tackon "catalogs/" language) (cat program ".catalog")))
                  (dest destination)
               )
               (copyfiles
                  (source (tackon (tackon "catalogs/" language) "taxSchedulerReg.catalog"))
                  (dest destination)
               )
            )
         )
         (set n (+ n 1))
      )
   )
)

(complete 75)

(
   (set lang
      (askoptions
         (prompt #which-docs)
         (help #which-docs-help @askoptions-help)
         (choices "Deutsch")
         (default guide-language)
      )
   )
   (set n 0)
   (while
      (set language
         (select n
            "deutsch"
            ""
         )
      )
      (
         (if (IN lang n)
            (
               (set destination
                  (askdir
                     (prompt #where-catalog)
                     (help @askdir-help)
                     (default (tackon helpdir language))
                  )
               )

               (copyfiles
                  (source (tackon (tackon "help/" language) (cat program ".guide")))
                  (dest destination)
               )
               (copyfiles
                  (source (tackon (tackon "help/" language) (cat program ".guide.info")))
                  (dest destination)
               )
            )
         )
         (set n (+ n 1))
      )
   )
)

(complete 100)
(exit)